Why Inline?¶

Do you want to know "Why would I use other languages in Perl?" or "Why should I use Inline to do it?"? I'll try to answer both.

Why would I use other languages in Perl?

The most obvious reason is performance. For an interpreted language, Perl is very fast. Many people will say "Anything Perl can do, C can do faster". (They never mention the development time :-) Anyway, you may be able to remove a bottleneck in your Perl code by using another language, without having to write the entire program in that language. This keeps your overall development time down, because you're using Perl for all of the non-critical code.

Another reason is to access functionality from existing API-s that use the language. Some of this code may only be available in binary form. But by creating small subroutines in the native language, you can "glue" existing libraries to your Perl. As a user of the CPAN, you know that code reuse is a good thing. So why throw away those Fortran libraries just yet?

If you are using Inline with the C language, then you can access the full internals of Perl itself. This opens up the floodgates to both extreme power and peril.

Maybe the best reason is "Because you want to!". Diversity keeps the world interesting. TMTOWTDI!

Why should I use Inline to do it?

There are already two major facilities for extending Perl with C. They are XS and SWIG. Both are similar in their capabilities, at least as far as Perl is concerned. And both of them are quite difficult to learn compared to Inline.

There is a big fat learning curve involved with setting up and using the XS environment. You need to get quite intimate with the following docs:

 * perlxs
 * perlxstut
 * perlapi
 * perlguts
 * perlmod
 * h2xs
 * xsubpp
 * ExtUtils::MakeMaker
    

With Inline you can be up and running in minutes. There is a C Cookbook with lots of short but complete programs that you can extend to your real-life problems. No need to learn about the complicated build process going on in the background. You don't even need to compile the code yourself. Inline takes care of every last detail except writing the C code.

Perl programmers cannot be bothered with silly things like compiling. "Tweak, Run, Tweak, Run" is our way of life. Inline does all the dirty work for you.

Another advantage of Inline is that you can use it directly in a script. You can even use it in a Perl one-liner. With XS and SWIG, you always set up an entirely separate module. Even if you only have one or two functions. Inline makes easy things easy, and hard things possible. Just like Perl.

Finally, Inline supports several programming languages (not just C and C++). As of this writing, Inline has support for C, C++, Java, Python, Ruby, Tcl, Assembler, Basic, Guile, Befunge, Octave, Awk, BC, TT (Template Toolkit), WebChat and even PERL. New Inline Language Support Modules (ILSMs) are regularly being added. See Inline-API for details on how to create your own ILSM.

The Basics¶

The most basic form for using Inline is:

    use Inline X => "X source code";

where 'X' is one of the supported Inline programming languages. The second parameter identifies the source code that you want to bind to Perl. The source code can be specified using any of the following syntaxes:

The DATA Keyword.

    use Inline Java => 'DATA';
    # Perl code goes here ...
    __DATA__
    __Java__
    /* Java code goes here ... */
    

The easiest and most visually clean way to specify your source code in an Inline Perl program is to use the special "DATA" keyword. This tells Inline to look for a special marker in your "DATA" filehandle's input stream. In this example the special marker is "__Java__", which is the programming language surrounded by double underscores.

In case you've forgotten, the "DATA" pseudo file is comprised of all the text after the "__END__" or "__DATA__" section of your program. If you're working outside the "main" package, you'd best use the "__DATA__" marker or else Inline will not find your code.

Using this scheme keeps your Perl code at the top, and all the ugly Java stuff down below where it belongs. This is visually clean and makes for more maintainable code. An excellent side benefit is that you don't have to escape any characters like you might in a Perl string. The source code is verbatim. For these reasons, I prefer this method the most.

The only problem with this style is that since Perl can't read the "DATA" filehandle until runtime, it obviously can't bind your functions until runtime. The net effect of this is that you can't use your Inline functions as barewords (without predeclaring them) because Perl has no idea they exist during compile time.

The FILE and BELOW keywords.

    use Inline::Files;
    use Inline Java => 'FILE';
    # Perl code goes here ...
    __JAVA__
    /* Java code goes here ... */
    

This is the newest method of specifying your source code. It makes use of the Perl module "Inline::Files" written by Damian Conway. The basic style and meaning are the same as for the "DATA" keyword, but there are a few syntactic and semantic twists.

First, you must say 'use Inline::Files' before you 'use Inline' code that needs those files. The special '"DATA"' keyword is replaced by either '"FILE"' or '"BELOW"'. This allows for the bad pun idiom of:

    use Inline C => 'BELOW';
    

You can omit the "__DATA__" tag now. Inline::Files is a source filter that will remove these sections from your program before Perl compiles it. They are then available for Inline to make use of. And since this can all be done at compile time, you don't have to worry about the caveats of the 'DATA' keyword.

This module has a couple small gotchas. Since Inline::Files only recognizes file markers with capital letters, you must specify the capital form of your language name. Also, there is a startup time penalty for using a source code filter.

At this point Inline::Files is alpha software and use of it is experimental. Inline's integration of this module is also fledgling at the time being. One of things I plan to do with Inline::Files is to get line number info so when an extension doesn't compile, the error messages will point to the correct source file and line number.

My best advice is to use Inline::Files for testing (especially as support for it improves), but use DATA for production and distributed/CPAN code.

Strings

    use Inline Java => <<'END';
    /* Java code goes here ... */
    END
    # Perl code goes here ...
    

You also just specify the source code as a single string. A handy way to write the string is to use Perl's "here document" style of quoting. This is ok for small functions but can get unwieldy in the large. On the other hand, the string variant probably has the least startup penalty and all functions are bound at compile time.

If you wish to put the string into a scalar variable, please be aware that the "use" statement is a compile time directive. As such, all the variables it uses must also be set at compile time, "before" the 'use Inline' statement. Here is one way to do it:

    my $code;
    BEGIN {
        $code = <<END;
    /* Java code goes here ... */
    END
    }
    use Inline Java => $code;
    # Perl code goes here ...
    

The bind() Function

An alternative to using the BEGIN block method is to specify the source code at run time using the 'Inline->bind()' method. (This is one of the interface exceptions mentioned above) The "bind()" method takes the same arguments as 'use Inline ...'.

    my $code = <<END;
    /* Java code goes here ... */
    END
    Inline->bind(Java => $code);
    

You can think of "bind()" as a way to "eval()" code in other programming languages.

Although bind() is a powerful feature, it is not recommended for use in Inline based modules. In fact, it won't work at all for installable modules. See instructions below for creating modules with Inline.

Other Methods

The source code for Inline can also be specified as an external filename, a reference to a subroutine that returns source code, or a reference to an array that contains lines of source code. (Note that if the external source file is in the current directory it must be specified with a leading './' - ie './file.ext' instead of simply 'file.ext'.) These methods are less frequently used but may be useful in some situations.

Shorthand

If you are using the 'DATA' or 'FILE' methods described above and there are no extra parameters, you can omit the keyword altogether. For example:

    use Inline 'Java';
    # Perl code goes here ...
    __DATA__
    __Java__
    /* Java code goes here ... */
    

or

    use Inline::Files;
    use Inline 'Java';
    # Perl code goes here ...
    __JAVA__
    /* Java code goes here ... */
    

More about the DATA Section¶

If you are writing a module, you can also use the DATA section for POD and AutoLoader subroutines. Just be sure to put them before the first Inline marker. If you install the helper module "Inline::Filters", you can even use POD inside your Inline code. You just have to specify a filter to strip it out.

You can also specify multiple Inline sections, possibly in different programming languages. Here is another example:

    # The module Foo.pm
    package Foo;
    use AutoLoader;
    use Inline C;
    use Inline C => DATA => FILTERS => 'Strip_POD';
    use Inline Python;
    1;
    __DATA__
    sub marine {
        # This is an autoloaded subroutine
    }
    =head1 External subroutines
    =cut
    __C__
    /* First C section */
    __C__
    /* Second C section */
    =head1 My C Function
    Some POD doc.
    =cut
    __Python__
    """A Python Section"""

An important thing to remember is that you need to have one "use Inline Foo => 'DATA'" for each "__Foo__" marker, and they must be in the same order. This allows you to apply different configuration options to each section.

Configuration Options¶

Inline trys to do the right thing as often as possible. But sometimes you may need to override the default actions. This is easy to do. Simply list the Inline configuration options after the regular Inline parameters. All congiguration options are specified as (key, value) pairs.

    use Inline (C => 'DATA',
                DIRECTORY => './inline_dir',
                LIBS => '-lfoo',
                INC => '-I/foo/include',
                PREFIX => 'XXX_',
                WARNINGS => 0,
               );

You can also specify the configuration options on a separate Inline call like this:

    use Inline (C => Config =>
                DIRECTORY => './inline_dir',
                LIBS => '-lfoo',
                INC => '-I/foo/include',
                PREFIX => 'XXX_',
                WARNINGS => 0,
               );
    use Inline C => <<'END_OF_C_CODE';

The special keyword 'Config' tells Inline that this is a configuration-only call. No source code will be compiled or bound to Perl.

If you want to specify global configuration options that don't apply to a particular language, just leave the language out of the call. Like this:

    use Inline Config => WARNINGS => 0;

The Config options are inherited and additive. You can use as many Config calls as you want. And you can apply different options to different code sections. When a source code section is passed in, Inline will apply whichever options have been specified up to that point. Here is a complex configuration example:

    use Inline (Config =>
                DIRECTORY => './inline_dir',
               );
    use Inline (C => Config =>
                LIBS => '-lglobal',
               );
    use Inline (C => 'DATA',         # First C Section
                LIBS => ['-llocal1', '-llocal2'],
               );
    use Inline (Config =>
                WARNINGS => 0,
               );
    use Inline (Python => 'DATA',    # First Python Section
                LIBS => '-lmypython1',
               );
    use Inline (C => 'DATA',         # Second C Section
                LIBS => [undef, '-llocal3'],
               );

The first "Config" applies to all subsequent calls. The second "Config" applies to all subsequent "C" sections (but not "Python" sections). In the first "C" section, the external libraries "global", "local1" and "local2" are used. (Most options allow either string or array ref forms, and do the right thing.) The "Python" section does not use the "global" library, but does use the same "DIRECTORY", and has warnings turned off. The second "C" section only uses the "local3" library. That's because a value of "undef" resets the additive behavior.

The "DIRECTORY" and "WARNINGS" options are generic Inline options. All other options are language specific. To find out what the "C" options do, see "Inline::C".

On and Off¶

If a particular config option has value options of 1 and 0, you can use the ENABLE and DISABLE modifiers. In other words, this:

    use Inline Config =>
               FORCE_BUILD => 1,
               CLEAN_AFTER_BUILD => 0;

could be reworded as:

    use Inline Config =>
               ENABLE => FORCE_BUILD,
               DISABLE => CLEAN_AFTER_BUILD;

Playing 'with' Others¶

Inline has a special configuration syntax that tells it to get more configuration options from other Perl modules. Here is an example:

    use Inline with => 'Event';

This tells Inline to load the module "Event.pm" and ask it for configuration information. Since "Event" has a C API of its own, it can pass Inline all of the information it needs to be able to use "Event" C callbacks seamlessly.

That means that you don't need to specify the typemaps, shared libraries, include files and other information required to get this to work.

You can specify a single module or a list of them. Like:

    use Inline with => qw(Event Foo Bar);

Currently, "Event" is the only module that works with Inline.

Inline Shortcuts¶

Inline lets you set many configuration options from the command line. These options are called 'shortcuts'. They can be very handy, especially when you only want to set the options temporarily, for say, debugging.

For instance, to get some general information about your Inline code in the script "Foo.pl", use the command:

    perl -MInline=INFO Foo.pl

If you want to force your code to compile, even if its already done, use:

    perl -MInline=FORCE Foo.pl

If you want to do both, use:

    perl -MInline=INFO -MInline=FORCE Foo.pl

or better yet:

    perl -MInline=INFO,FORCE Foo.pl

The Inline DIRECTORY¶

Inline needs a place to build your code and to install the results of the build. It uses a single directory named '.Inline/' under normal circumstances. If you create this directory in your home directory, the current directory or in the directory where your program resides, Inline will find and use it. You can also specify it in the environment variable "PERL_INLINE_DIRECTORY" or directly in your program, by using the "DIRECTORY" keyword option. If Inline cannot find the directory in any of these places it will create a '_Inline/' directory in either your current directory or the directory where your script resides.

One of the key factors to using Inline successfully, is understanding this directory. When developing code it is usually best to create this directory (or let Inline do it) in your current directory. Remember that there is nothing sacred about this directory except that it holds your compiled code. Feel free to delete it at any time. Inline will simply start from scratch and recompile your code on the next run. If you have several programs that you want to force to recompile, just delete your '.Inline/' directory.

It is probably best to have a separate '.Inline/' directory for each project that you are working on. You may want to keep stable code in the <.Inline/> in your home directory. On multi-user systems, each user should have their own '.Inline/' directories. It could be a security risk to put the directory in a shared place like "/tmp/".

Debugging Inline Errors¶

All programmers make mistakes. When you make a mistake with Inline, like writing bad C code, you'll get a big error report on your screen. This report tells you where to look to do the debugging. Some languages may also dump out the error messages generated from the build.

When Inline needs to build something it creates a subdirectory under your "DIRECTORY/build/" directory. This is where it writes all the components it needs to build your extension. Things like XS files, Makefiles and output log files.

If everything goes OK, Inline will delete this subdirectory. If there is an error, Inline will leave the directory intact and print its location. The idea is that you are supposed to go into that directory and figure out what happened.

Read the doc for your particular Inline Language Support Module for more information.

The 'config' Registry File¶

Inline keeps a cached file of all of the Inline Language Support Module's meta data in a file called "config". This file can be found in your "DIRECTORY" directory. If the file does not exist, Inline creates a new one. It will search your system for any module beginning with "Inline::". It will then call that module's "register()" method to get useful information for future invocations.

Whenever you add a new ILSM, you should delete this file so that Inline will auto-discover your newly installed language module. (This should no longer be necessary as of Inline-0.49.)

DIRECTORY¶

The "DIRECTORY" config option is the directory that Inline uses to both build and install an extension.

Normally Inline will search in a bunch of known places for a directory called '.Inline/'. Failing that, it will create a directory called '_Inline/'

If you want to specify your own directory, use this configuration option.

Note that you must create the "DIRECTORY" directory yourself. Inline will not do it for you.

NAME¶

You can use this option to set the name of your Inline extension object module. For example:

    use Inline C => 'DATA',
               NAME => 'Foo::Bar';

would cause your C code to be compiled in to the object:

    lib/auto/Foo/Bar/Bar.so
    lib/auto/Foo/Bar/Bar.inl

(The .inl component contains dependency information to make sure the source code is in sync with the executable)

If you don't use NAME, Inline will pick a name for you based on your program name or package name. In this case, Inline will also enable the AUTONAME option which mangles in a small piece of the MD5 fingerprint into your object name, to make it unique.

AUTONAME¶

This option is enabled whenever the NAME parameter is not specified. To disable it say:

    use Inline C => 'DATA',
               DISABLE => 'AUTONAME';

AUTONAME mangles in enough of the MD5 fingerprint to make your module name unique. Objects created with AUTONAME will never get replaced. That also means they will never get cleaned up automatically.

AUTONAME is very useful for small throw away scripts. For more serious things, always use the NAME option.

VERSION¶

Specifies the version number of the Inline extension object. It is used only for modules, and it must match the global variable $VERSION. Additionally, this option should used if (and only if) a module is being set up to be installed permanently into the Perl sitelib tree. Inline will croak if you use it otherwise.

The presence of the VERSION parameter is the official way to let Inline know that your code is an installable/installed module. Inline will never generate an object in the temporary cache (_Inline/ directory) if VERSION is set. It will also never try to recompile a module that was installed into someone's Perl site tree.

So the basic rule is develop without VERSION, and deliver with VERSION.

WITH¶

"WITH" can also be used as a configuration option instead of using the special 'with' syntax. Do this if you want to use different sections of Inline code with different modules. (Probably a very rare usage)

    use Event;
    use Inline C => DATA => WITH => 'Event';

Modules specified using the config form of "WITH" will not be automatically required. You must "use" them yourself.

GLOBAL_LOAD¶

This option is for compiled languages only. It tells Inline to tell DynaLoader to load an object file in such a way that its symbols can be dynamically resolved by other object files. May not work on all platforms. See the "GLOBAL" shortcut below.

UNTAINT¶

You can use this option whenever you use Perl's "-T" switch, for taint checking. This option tells Inline to blindly untaint all tainted variables. (This is generally considerd to be an appallingly insecure thing to do, and not to be recommended - but the option is there for you to use if you want. Please consider using something other than Inline for scripts that need taint checking.) It also turns on SAFEMODE by default. See the "UNTAINT" shortcut below. You will see warnings about blindly untainting fields in both %ENV and Inline objects. If you want to silence these warnings, set the Config option NO_UNTAINT_WARN => 1. There can be some problems untainting Inline scripts where older versions of Cwd, such as those that shipped with early versions of perl-5.8 (and earlier), are installed. Updating Cwd will probably solve these problems.

SAFEMODE¶

Perform extra safety checking, in an attempt to thwart malicious code. This option cannot guarantee security, but it does turn on all the currently implemented checks. (Currently, the only "currently implemented check" is to ensure that the "DIRECTORY" option has also been used.)

There is a slight startup penalty by using SAFEMODE. Also, using UNTAINT automatically turns this option on. If you need your code to start faster under "-T" (taint) checking, you'll need to turn this option off manually. Only do this if you are not worried about security risks. See the "UNSAFE" shortcut below.

FORCE_BUILD¶

Makes Inline build (compile) the source code every time the program is run. The default is 0. See the "FORCE" shortcut below.

BUILD_NOISY¶

Tells ILSMs that they should dump build messages to the terminal rather than be silent about all the build details.

BUILD_TIMERS¶

Tells ILSMs to print timing information about how long each build phase took. Usually requires "Time::HiRes".

CLEAN_AFTER_BUILD¶

Tells Inline to clean up the current build area if the build was successful. Sometimes you want to DISABLE this for debugging. Default is 1. See the "NOCLEAN" shortcut below.

CLEAN_BUILD_AREA¶

Tells Inline to clean up the old build areas within the entire Inline DIRECTORY. Default is 0. See the "CLEAN" shortcut below.

PRINT_INFO¶

Tells Inline to print various information about the source code. Default is 0. See the "INFO" shortcut below.

PRINT_VERSION¶

Tells Inline to print Version info about itself. Default is 0. See the "VERSION" shortcut below.

REPORTBUG¶

Puts Inline into 'REPORTBUG' mode, which is what you want if you desire to report a bug.

REWRITE_CONFIG_FILE¶

Default is 0, but setting 'REWRITE_CONFIG_FILE => 1' will mean that the existing configuration file in the Inline DIRECTORY will be overwritten. (This is useful if the existing config file is not up to date as regards supported languages.)

WARNINGS¶

This option tells Inline whether to print certain warnings. Default is 1.