What Makes This Different?¶

What makes this module special compared to all the other method generating modules ("SEE ALSO")? By overriding the get() and set() methods you can alter the behavior of the accessors class-wide. Also, the accessors are implemented as closures which should cost a bit less memory than most other solutions which generate a new method for each accessor.

new¶

    my $obj = Class->new;
    my $obj = $other_obj->new;
    my $obj = Class->new(\%fields);
    my $obj = $other_obj->new(\%fields);

Class::Accessor provides a basic constructor. It generates a hash-based object and can be called as either a class method or an object method.

It takes an optional %fields hash which is used to initialize the object (handy if you use read-only accessors). The fields of the hash correspond to the names of your accessors, so...

    package Foo;
    use base qw(Class::Accessor);
    Foo->mk_accessors('foo');
    my $obj = Class->new({ foo => 42 });
    print $obj->foo;    # 42

however %fields can contain anything, new() will shove them all into your object. Don't like it? Override it.

mk_accessors¶

    Class->mk_accessors(@fields);

This creates accessor/mutator methods for each named field given in @fields. Foreach field in @fields it will generate two accessors. One called "field()" and the other called "_field_accessor()". For example:

    # Generates foo(), _foo_accessor(), bar() and _bar_accessor().
    Class->mk_accessors(qw(foo bar));

See "Overriding autogenerated accessors" in CAVEATS AND TRICKS for details.

mk_ro_accessors¶

  Class->mk_ro_accessors(@read_only_fields);

Same as mk_accessors() except it will generate read-only accessors (ie. true accessors). If you attempt to set a value with these accessors it will throw an exception. It only uses get() and not set().

    package Foo;
    use base qw(Class::Accessor);
    Class->mk_ro_accessors(qw(foo bar));
    # Let's assume we have an object $foo of class Foo...
    print $foo->foo;  # ok, prints whatever the value of $foo->{foo} is
    $foo->foo(42);    # BOOM!  Naughty you.

mk_wo_accessors¶

  Class->mk_wo_accessors(@write_only_fields);

Same as mk_accessors() except it will generate write-only accessors (ie. mutators). If you attempt to read a value with these accessors it will throw an exception. It only uses set() and not get().

NOTE I'm not entirely sure why this is useful, but I'm sure someone will need it. If you've found a use, let me know. Right now its here for orthoginality and because its easy to implement.

    package Foo;
    use base qw(Class::Accessor);
    Class->mk_wo_accessors(qw(foo bar));
    # Let's assume we have an object $foo of class Foo...
    $foo->foo(42);      # OK.  Sets $self->{foo} = 42
    print $foo->foo;    # BOOM!  Can't read from this accessor.

follow_best_practice¶

In Damian's Perl Best Practices book he recommends separate get and set methods with the prefix set_ and get_ to make it explicit what you intend to do. If you want to create those accessor methods instead of the default ones, call:

    __PACKAGE__->follow_best_practice

accessor_name_for / mutator_name_for¶

You may have your own crazy ideas for the names of the accessors, so you can make those happen by overriding "accessor_name_for" and "mutator_name_for" in your subclass. (I copied that idea from Class::DBI.)

Modifying the behavior of the accessor¶

Rather than actually modifying the accessor itself, it is much more sensible to simply override the two key methods which the accessor calls. Namely set() and get().

If you -really- want to, you can override make_accessor().

set¶

    $obj->set($key, $value);
    $obj->set($key, @values);

set() defines how generally one stores data in the object.

override this method to change how data is stored by your accessors.

get¶

    $value  = $obj->get($key);
    @values = $obj->get(@keys);

get() defines how data is retreived from your objects.

override this method to change how it is retreived.

make_accessor¶

    $accessor = Class->make_accessor($field);

Generates a subroutine reference which acts as an accessor for the given $field. It calls get() and set().

If you wish to change the behavior of your accessors, try overriding get() and set() before you start mucking with make_accessor().

make_ro_accessor¶

    $read_only_accessor = Class->make_ro_accessor($field);

Generates a subroutine refrence which acts as a read-only accessor for the given $field. It only calls get().

Override get() to change the behavior of your accessors.

make_wo_accessor¶

    $read_only_accessor = Class->make_wo_accessor($field);

Generates a subroutine refrence which acts as a write-only accessor (mutator) for the given $field. It only calls set().

Override set() to change the behavior of your accessors.

Don't make a field called DESTROY¶

This is bad. Since DESTROY is a magical method it would be bad for us to define an accessor using that name. Class::Accessor will carp if you try to use it with a field named "DESTROY".

Overriding autogenerated accessors¶

You may want to override the autogenerated accessor with your own, yet have your custom accessor call the default one. For instance, maybe you want to have an accessor which checks its input. Normally, one would expect this to work:

    package Foo;
    use base qw(Class::Accessor);
    Foo->mk_accessors(qw(email this that whatever));
    # Only accept addresses which look valid.
    sub email {
        my($self) = shift;
        my($email) = @_;
        if( @_ ) {  # Setting
            require Email::Valid;
            unless( Email::Valid->address($email) ) {
                carp("$email doesn't look like a valid address.");
                return;
            }
        }
        return $self->SUPER::email(@_);
    }

There's a subtle problem in the last example, and its in this line:

    return $self->SUPER::email(@_);

If we look at how Foo was defined, it called mk_accessors() which stuck email() right into Foo's namespace. There *is* no SUPER::email() to delegate to! Two ways around this... first is to make a "pure" base class for Foo. This pure class will generate the accessors and provide the necessary super class for Foo to use:

    package Pure::Organic::Foo;
    use base qw(Class::Accessor);
    Pure::Organic::Foo->mk_accessors(qw(email this that whatever));
    package Foo;
    use base qw(Pure::Organic::Foo);

And now Foo::email() can override the generated Pure::Organic::Foo::email() and use it as SUPER::email().

This is probably the most obvious solution to everyone but me. Instead, what first made sense to me was for mk_accessors() to define an alias of email(), _email_accessor(). Using this solution, Foo::email() would be written with:

    return $self->_email_accessor(@_);

instead of the expected SUPER::email().

ORIGINAL AUTHOR¶

Michael G Schwern <schwern@pobox.com>

THANKS¶

Liz and RUZ for performance tweaks.

Tels, for his big feature request/bug report.